First let’s create a new flash document, and create a play button , add it in the middle of the stage and give it an instance name of “gos”, or download the starter files here. Now that we have our document ready let’s create our variables:

var music=new Sound(new URLRequest("song.mp3"));//the variable in which we load our song
var ba:ByteArray= new ByteArray();//the needed byte array so we can analyze the sound
var spr:Sprite=new Sprite();//a new sprite in which to draw
var arr:Array=[];//and an array to keep the line data

addChild(spr);//add the sprite to the display list

Let’s create the function that plays the music and starts the animation:
gos.addEventListener(MouseEvent.CLICK,doCli);

function doCli(e:MouseEvent){
gos.visible=false;
stage.addEventListener(Event.ENTER_FRAME, loop);
music.play();
}

And now the function that does all the drawing and sound analyzing :
function loop(e:Event):void {
spr.graphics.clear();//clear everything drawn
spr.graphics.moveTo(-90,stage.stageHeight/2);//move the graphics outside the visible area

SoundMixer.computeSpectrum(ba,true);//use the SoundMixer to analyze the sound

//create a for loop to set the properties of the line

for (var i:uint=0; i<256; i=i+4) {

var num:Number= ba.readFloat()*10;

var obj:Object=new Object();
obj.x=mouseX;
obj.y=mouseY;
obj.thick=num+3;
arr.push(obj);
}

//use another for loop to draw
for(var i2:uint=0;i2;i2<arr.length;i2++){

//decrees the x position on every point to achieve the moving canvas effect
arr[i2].x-=5;
spr.graphics.lineStyle(arr[i2].thick);
spr.graphics.lineTo(arr[i2].x,arr[i2].y);

//remove any point that goes beyond -100 on the x axis so that the app doesn't run slow
if(arr[i2].x<-100){
arr.splice(i2,1);
}
}
}

Now let’s test the movie and you should have something similar to this:

You can download the finished files here.

On the labuant website, your every movement is recorded so that you can play your custom “video” after you have finished “playing” with the site. In order to do this you could save all the data in a new array, and create a custom “for” loop to draw your movements automatic. Remember this is not the best way to do something like this, it is just an idea on how to do something like this.

Articol favorit

import org.alivepdf.pdf.PDF;
import org.alivepdf.layout.Size;
import org.alivepdf.saving.Method;
import org.alivepdf.layout.Unit;
import org.alivepdf.layout.Orientation;

Now we can start creating our pdf file:

var doc:PDF=new PDF(Orientation.PORTRAIT,Unit.MM,Size.A4);

//you can have the orientation either in PORTRAIT or in LANDSCAPE mode
//the unit can be: MM,POINT,CM,INCHES
//Size defines the size of the document page witch can be: //A3,A4,A5,LETTER, LEGAL,TABLOID

To add a new page to the pdf file you simply call the addPage method:

doc.addPage();

Now let’s create the file and filestream, so we can save the pdf:

var stream:FileStream=new FileStream();
var file:File=File.desktopDirectory.resolvePath("mydoc.pdf");
stream.open(file,FileMode.WRITE);

The pdf file will be saved on the user’s desktop as we defined the path. Now it’s time for the function that creates and saves the file:

but.addEventListener(MouseEvent.CLICK,save);

function save(e:MouseEvent):void{
doc.addText(txt.text,5,10);//add the text from text input field and position it at the x:5 and y:10
var byte:ByteArray=doc.save(Method.LOCAL); //if you are publishing for a web application you should set the Method.REMOTE
stream.writeBytes(byte);
stream.close();
}

If we run our project we should have a little pdf creating app.You can download the finished source files here. The AlivePDF library has a lot of options like: adding an image to the file using the addImage(displayObject) method, or setting the font style, hyperlinks and much more. If you want to learn more about AlivePDF you can visit the official site , or the tutorials page here (tough some of the tutorials were written on an earlier version of the library and may not work with the current version).

Articol favorit

Articol favorit

Si ce tip de aplicatie era mai potrivita pentru asa ceva decat un joc (cu muste dupa ideea lui Ciprica si Maximilian)? Ce a iesit puteti vedea descarcand aplicatia de aici pentru Windows Mobile (jocul este gandit pentru telefoanele cu touchscreen). Pentru a putea folosi Adobe Mobile Packager trebuie sa descarcati aplicatia de aici, o instalati apoi urmati pasii din tutorialele video de aici. Iar pentru a putea rula aplicatiile pe telefonul mobil va trebui sa descarcati o noua versiune de Flash Lite Player de aici. Momentan aplicatiile merg pe un numar restrans de telefoane mobile ce se gasesc in lista de aici. Trebuie sa recunoastem ca ne-am fi dorit o data cu lansarea acestei aplicatii sa avem mai mult control asupra terminalului mobil, dar poate vor veni in timp. Puteti descarca si sursa jocului de aici pentru a vedea cum a fost creat.

Articol favorit

Puteti descarca aplicatia de aici,iar pentru a vedea codul sursa sau pentru a schimba limbile (in caz ca se doreste invatarea unei alte limbi) puteti descarca sursa de aici. Hasta luego!

Articol favorit

First you need to create you 3d model (for this tutorial I build a model that resembles a tank) or download a model from google 3D warehouse. You can get the starter files here.

To get things started we create a new flash file and start importing all the papervision classes that we need:


import org.papervision3d.scenes.Scene3D;
import org.papervision3d.view.Viewport3D;
import org.papervision3d.render.BasicRenderEngine;
import org.papervision3d.objects.DisplayObject3D;
import org.papervision3d.objects.parsers.Collada;
import org.papervision3d.cameras.Camera3D;
import org.papervision3d.materials.utils.MaterialsList;
import org.papervision3d.materials.shadematerials.FlatShadeMaterial;
import org.papervision3d.lights.PointLight3D;
import org.papervision3d.materials.shaders.CellShader;

Now let’s prepare the 3d scene:

var cam:Camera3D=new Camera3D();
var scena:Scene3D=new Scene3D();
var view:Viewport3D=new Viewport3D();
var pl:PointLight3D = new PointLight3D();
var render:BasicRenderEngine=new BasicRenderEngine();

So in order to create a papervision scene we need a camera object, a scene3D, viewport3D and a RenderEngine this is necesary for a papervision scene.

Now create the materials:

//the glow filter will give a nice outer stroke to the 3d model
var gf:GlowFilter=new GlowFilter(0x000000,1,5,5,4,1);
//this is a material from the papervision 3d library that uses a light to cast shadows on the objects
var cs:CellShader = new CellShader(pl);
//the material list contains all the materials for the different faces, in this case all the faces
//are flast shaded
var ml:MaterialsList = new MaterialsList( { all:new FlatShadeMaterial(pl) } );

Now import the 3d model and add it to the scene object:

var tank:DisplayObject3D=new Collada("tnk.dae",ml);
//because the 3d modeling tool used is different this values may need some
//trial and error before getting them right
tank.scaleX=tank.scaleY=tank.scaleZ=0.3;
tank.y=-300;
tank.z=300;
tank.rotationY=90;
//all you filters are not added to the actual model but on the viewport 3d
view.filters=[gf];
//add the tank object to the scene 3d
scena.addChild(tank);
//add the viewport to the flash display list
addChild(view);

To be able to render animations you need to encapsulate the render function in a EnterFrame event:

addEventListener(Event.ENTER_FRAME,anim);

function anim(e:Event){
tank.rotationY++;
//the renderScene function expects 3 parameters: the scene3D where all the objects are
//the camera and the viewport3D
render.renderScene(scena,cam,view);
}

Now test the movie and you should get the following result:

You can download the final source files here.

Articol favorit

Now let’s arrange our stage. First of all we add the MovieClip that contains the image and give it an instance name of “img” on top of that we add the holder and give it an instance name of “scrol”.

Let’s begin the coding: add the following code in the first frame…

var first:Boolean=true;
var bmp:Bitmap=new Bitmap();

The variable “first” tell’s us if it’s the first time that we call the draw function, if not we can clear our bitmap called “bmp”.  Now will add an Event listener to our “scrol” MovieClip.

scrol.addEventListener(MouseEvent.MOUSE_DOWN,strtDrag);

function strtDrag(e:MouseEvent){
first=false;//we set the variable first to false
scrol.my=scrol.mouseY;//we save the current mouse Y
scrol.removeEventListener(MouseEvent.MOUSE_DOWN,strtDrag);
scrol.addEventListener(MouseEvent.MOUSE_MOVE,repos);
scrol.addEventListener(MouseEvent.MOUSE_UP,rem);
}

When we mouse down on our “scrol” MovieClip we remove the event listener for mouse down and add two new events: one to listen for the mouse move event so that our movieclip will follow the mouse on the Y axis and another to listen for the mouse up event so we can stop the draging. Now let’s add our other functions.

function rem(e:MouseEvent){
scrol.addEventListener(MouseEvent.MOUSE_DOWN,strtDrag);
scrol.removeEventListener(MouseEvent.MOUSE_MOVE,repos);
scrol.removeEventListener(MouseEvent.MOUSE_UP,rem);
}

function repos(e:MouseEvent){
scrol.y=mouseY-scrol.my;//change the y position
beginDraw();//the function that does the bitmap drawing
}

If you are asking: why not use “startDrag()” instead of all this code. The answer is that in order to use it only on the Y axis you should create a new Rectangle variable so you can limit it only on the Y axis. Because the center point of “scrol” is in the top left corner we need to substract from the current mouse position our variable. Now let’s create the beginDraw function:

function beginDraw() {
if(!first){
scrol.hld.removeChild(bmp);
}
var bmd:BitmapData=new BitmapData(scrol.width,scrol.height);
var bmd2:BitmapData=new BitmapData(444,400);
var rectangle:Rectangle=new Rectangle(0,scrol.y,scrol.width,scrol.height);
bmd2.draw(img);
bmd.copyPixels(bmd2,rectangle,new Point(0,0));
bmd2.dispose();
bmp.bitmapData=bmd;
var bf:BlurFilter=new BlurFilter(6,6,3);
bmp.filters=[bf];
scrol.hld.addChild(bmp);
}

beginDraw();

In order to draw just the part of the image that is under the “scrol” MovieClip,  create two bitmapData variables: one to copy the whole image and another to copy only the pixels that we need.Finally we add a blur filter to the bitmap and call our “beginDraw” function so we can see the effect the first time we enter the flash movie. When you test your movie it should look like this:

You can download the finished source files here.

Articol favorit

RSS (an abbreviation for Really Simple Syndication) is a family of Web feed formats used to publish frequently updated works—such as blog entries, news headlines, audio, and video—in a standardized format… more information here.

This is how the finished application will look like:

To get things  started I have created a new air file and drew the above graphics. The band at the top of the application holds the title of the post,  is a MovieClip with an instance name of “post” and inside it there is a dynamic textField with an instance name of “the_title”.  The black MovieClip that holds the text of the post has an instance name of “all” and inside it there is a dynamic textField with an instance name of “descrip”.You can get the starter files here.

Let’s add the first lines of code:
//we declare our variables
var loader:URLLoader = new URLLoader();
var xml:XML;
//this will hold all the information
//we need about the feed
var posts:Array=new Array();
//this will remember which post we are reading
var cur_comm:uint=0;
//this tells if the title is scrolling
var scrolling:Boolean=true;
//the maximum scroll x position
var relx:Number=0;

Now let’s add the event listeners that we need:
//listener for the rss feed
loader.addEventListener(Event.COMPLETE, onLoaded);
//when you Mouse Down on the title area
//you can drag the application
top.addEventListener(MouseEvent.MOUSE_DOWN,misca);
//listener for the close button
cls.addEventListener(MouseEvent.CLICK,closeapp);
//the listener that will scroll our title
top.addEventListener(Event.ENTER_FRAME,scroll_text);
cls.buttonMode=true;
top.the_title.autoSize="left";

Now to create the timer that will display the posts from our feed:
//the timer expects time in milliseconds, 1000 milliseconds =1 sec
var timerObject:Timer = new Timer(10000);
//at each 10 seconds it will change the post that we are viewing
timerObject.addEventListener(TimerEvent.TIMER, start_comments);

Now we create the function that parses the feed, just like an xml file:
//the function that will parse the rss
function onLoaded(e:Event):void{
xml = new XML(e.target.data);
//all the information that we need
//is located in the root.channel.item node
//of the feed
var il:XMLList=xml.channel.item;
for(var i:uint=0;i
//create a new object
var obj:Object=new Object();
//get the link for the full post
obj.link=il[i].link.text();
//get the title of the post
obj.title=il[i].title.text();
//get the description of the post
obj.descr=il[i].description.text();
//add the object in our array
posts.push(obj);
}
//we start our timer object
timerObject.start();
//we add our first post in the textFields
all.descrip.htmlText=unescape(posts[0].descr);
top.the_title.text=posts[0].title;
//create a new timer object, that refreshes
//the feed every 10 minutes
var timerObject2:Timer = new Timer(600000);
timerObject2.addEventListener(TimerEvent.TIMER, refresh_feed);
timerObject2.start();
//we add the event listener that handles
//the clicks on out description
all.addEventListener(MouseEvent.CLICK,go_page);
}
//we load the feed
loader.load(new URLRequest("http://jurnal.tripmedia.ro/feed"));

Now create the function that changes thepost that we are showing every 10 seconds:
function start_comments(e:TimerEvent):void{
//every time the timer reaches
//10 seconds we change the post
//that we are viewing
cur_comm++;
if(cur_comm>posts.length-1){
cur_comm=0;
}
all.descrip.htmlText=unescape(posts[cur_comm].descr);
top.the_title.text=posts[cur_comm].title;
}

Now the function that refreshes the feed every 10 minutes is actualy realoading the feed all over again:
function refresh_feed(e:TimerEvent):void{
loader.load(new URLRequest("http://jurnal.tripmedia.ro/feed"));
}

Next step is to create the function that will handle the closing of the application, the dragging of the application and the click that opens the web browser to read the full post :
function misca(evu:MouseEvent):void{
this.stage.nativeWindow.startMove();
}

function closeapp(e:MouseEvent):void {
NativeApplication.nativeApplication.exit();
}

function go_page(e:MouseEvent):void{
var req:URLRequest=new URLRequest(posts[cur_comm].link);
navigateToURL(req,"_self");
}

And now our final function, the function that handles the scrolling of the title if it is too long to fit in our application:

function scroll_text(e:Event):void{
//we calculate the maximum x scroll
//to the left
relx=-(top.the_title.width-172);
//we scroll the text only if there are more
//than 28 characters in it, if you are
//wondering why 28? well 28 is the maximum
//number of characters that the user can
//see because of the the dynamic textField
if(top.the_title.length>28){
//if it is scrolling to the left
if(scrolling){
top.the_title.x-=0.3;
//if the title is lower than relx
//we move tot the right
if(top.the_title.x<relx){
scrolling=false;
}
}else if(!scrolling){
top.the_title.x+=0.3;
if(top.the_title.x>0){
scrolling=true;
}
}
}
}

You can download the finished application here. Or you can download the AIR Installer file here. From this example you can build you own rss reader application, there might be a couple of extensions to this app: letting the user input his own feed location, reading and displaying more feeds at once, alarm the user that there is a new feed, managing the feed where you can save all your feeds and cycle through them and many other features. Feel free to use the code as you like and share with us what you have created.

Articol favorit

To start things off, I have created a new flash document called photo.fla and saved it, a xml file called gall.xml and 7 pics 200×200. If you don’t have a desire for creating this files for yourself you may download the start files right here.

Let’s begin by creating the needed variables:

var arr:Array=new Array();//this holds out all xml data
var pics:Array=new Array();//this holds out all the images
var str:Number=-90;//this is for the maximum angle
var decr:Number=0;//this is the angle increment
var nr:Number=0;//this is the number of the picture
var uldr:URLLoader=new URLLoader();//the url loader variable to load the xml

Now let’s load the xml:


//add a new event listener for the loader
uldr.addEventListener(Event.COMPLETE,doArr);
//load our xml
uldr.load(new URLRequest("gall.xml"));

Now add the code for the Event.Complete function called doArr. This function parses the xml file.

//create the Event.COMPLETE function that parses the xml
function doArr(e:Event){
//create a new xml variable
var xml:XML=new XML(e.target.data);
//create a new xml list variable
var il:XMLList=xml.item;
//parse the xml
for(var i:uint=0;i<il.length();i++){
arr.push(il[i].linku);
}
//after the xml has been parsed, calculate the
//rotation distance between photos
decr=-Math.round((str/il.length()));
//call the function that creates the gallery
createGall();
}

Let’s construct the createGall function:


//create the function that loads our gallery images
function createGall(){
//parse the array that contains our images
for(var i:uint=0;i<arr.length;i++){
//create a new url loader
var ldr:Loader=new Loader();
//load the image locate at the i position in the array
ldr.load(new URLRequest(arr[i]));
//add a new event listener that ads the image to the stage
ldr.contentLoaderInfo.addEventListener(Event.COMPLETE,doImg);
}
}

Write the function that adds the gallery to the Stage.

function doImg(e:Event){
//create a new movieclip to hold the image
var t:MovieClip=new MovieClip();
//create a new sprite in wich to draw a white rectangle
var spr:Sprite=new Sprite();
//we set the fill color to white
spr.graphics.beginFill(0xFFFFFF);
//we draw the rectangle at x:0,y:0, width:210,height:210
//that means +10 of the width and height of our image (200x200)
spr.graphics.drawRect(0,0,210,210);
//and drawing
spr.graphics.endFill();
//we position our sprite
spr.x=-spr.width/2;
spr.y=-spr.height+5;
//create a new bitmap that receives the loaded image
var bm:Bitmap=Bitmap(e.target.content);
//position the image
bm.x=-bm.width/2;
bm.y=-bm.height;
//smooth the image
bm.smoothing=true;
//add the sprite and image to our movieclip
t.addChild(spr);
t.addChild(bm);
//position the movieclip on the stage
t.x=300;
t.y=300;
//set the rotation in 3d space
t.rotationY=-40;
t.rotationX=str;
str+=decr;
//create a new rot property for the movieclip
//that holds the rotation on the X axis
t.rot=t.rotationX;
//the number of the picture
t.nr=nr;
nr++;
//push the picture in the pics array
pics.push(t);
//add the movieclip to the Stage
addChild(t);
//add a new event listener to the movieclip
//that animates our gallery when we click an image
t.addEventListener(MouseEvent.CLICK,entr);
}

Now let’s write the click function that animates the gallery:

function entr(e:MouseEvent){
//check to see if the clicked image is in front
if(e.currentTarget.nr==nr-1){
nr-=1;
//add a new event to the clicked image
e.currentTarget.addEventListener(Event.ENTER_FRAME,anim);
for(var i:uint=0;i<pics.length;i++){
//all the images in a lower postion than the clicked image
//are animated with another function
if(i<e.currentTarget.nr){
//create a temporary movieclip
var tmp:MovieClip=MovieClip(pics[i]);
//animate th movieclip
tmp.addEventListener(Event.ENTER_FRAME,anim2);
}
}
//remove the click event from the current clicked image
e.currentTarget.removeEventListener(MouseEvent.CLICK,entr);
}
}

Add the following code to create the first animation function:


function anim(e:Event){
if(e.currentTarget.rotationX<90){
//roatate the front image
e.currentTarget.rotationX+=(90-e.currentTarget.rotationX)/10;
//decrease the alpha of the image
e.currentTarget.alpha+=(0-e.currentTarget.alpha)/10;
}
}

Now the code that animates the rest of the images:

function anim2(e:Event){
//calculate the rotation at wich the picture
//will be set at the final of the animation
var nrx:Number=e.currentTarget.rot+decr;
//animate the rotation
e.currentTarget.rotationX+=Math.round((nrx-e.currentTarget.rotationX)/10);
//check to see the rotation value
if(e.currentTarget.rotationX>=nrx-4){
//remove this function
e.currentTarget.removeEventListener(Event.ENTER_FRAME,anim2);
//set the rot property
e.currentTarget.rot=nrx;
}
}

Let’s test our movie to see the final result:

You can get the final source files here , play with it and show me what you come up with.

Articol favorit

Let’s get started by creating a new flash file and adding the following code:

Create a new HTML loader variable
var htmlL:HTMLLoader=new HTMLLoader();
set the dimensions of your html content to the
dimensions of the stage
htmlL.width=stage.stageWidth;
htmlL.height=stage.stageHeight;
add the html to the stage
addChild(htmlL);
this next line disables cache for your browser
if you set it to true when you revisit a web page
it will take some components of that web site from
the cache saved on your computer
htmlL.cacheResponse=false;
this loads the desired web page
htmlL.load(new URLRequest("http://tripmedia.ro"));

Now test your file and you will see the web page. This is just an example to show what Adobe Air can do, the browser is not completly functional because the user can not input the adress and there is no UI(user interface) . But this is something that everybody can experiment with and let their imagination loose.

Articol favorit

First … What is Adobe AIR? Adobe AIR is a cross-platform runtime environment for building rich Internet applications using Adobe Flash, Adobe Flex, HTML, or Ajax, that can be deployed as a desktop application.

For this tutorial you will need at least Adobe Flash CS3 and the latest Adobe Air runtime for Flash. In order to start our application I’ve created a background movie clip called “back” , two buttons (one to add new contacts with an instance name of “plus” and one to close the application with an instance name of “xu“). In the first frame I have a combo box component with an instance name of “lister” , in the second frame two input text fields with the instance names of “nume” and “tel“. If you don’t want to create this for yourself you can download the start.fla file.

Add the following code to the first frame of your movie:

stop();

//create a new sql connection
var conn:SQLConnection= new SQLConnection();
//add an event handeler for the open event
conn.addEventListener(SQLEvent.OPEN, openHandler);
//create the database if it doesn't exist, otherwise just opens it
var dbFile:File =File.applicationDirectory.resolvePath ("exemplu.db");
conn.openAsync(dbFile);

Now add a new function that creates a table in the database. To do so, write the following code in the first frame of your application:

function openHandler(event:SQLEvent):void {
//create a new sql statement
var sql:SQLStatement=new SQLStatement();
//set the statement to connect to our database
sql.sqlConnection=conn;
//parse the sql command that creates the table if it doesn't exist
sql.text= "CREATE TABLE IF NOT EXISTS contacte(" +
"id INTEGER PRIMARY KEY AUTOINCREMENT, " +
"nume TEXT, " +
"telefon INTEGER)";
//add a new event listener to the sql when it completes creating the table
sql.addEventListener(SQLEvent.RESULT,retrieveData);
//call the execute function to execute our statement
sql.execute();
}

The next step is to create the function that retrieves the data from the table in the database. Just write the following code in the first frame of your application:

function retrieveData(event:SQLEvent = null):void {
//create a new sql statemant
var sql:SQLStatement = new SQLStatement();
sql.sqlConnection=conn;
//this sql command retrieves all the fields from our
//table in the database and orders it by name
sql.text =  "SELECT id, nume, " +
"telefon " +
"FROM contacte ORDER BY nume";
//add a new event listener if there is data
//to display it
sql.addEventListener(SQLEvent.RESULT, selectHandler);
sql.execute();
}

Now it is time to create the function that shows the contacts in the list component. To create it just insert in the first frame of your file the following code:

function selectHandler(event:SQLEvent):void {
//first we clear our list
lister.removeAll();
//the we create a result variable that holds
//all our contacts
var result:SQLResult=event.target.getResult();
//we check if results is not empty
if (result!=null&&result.data!=null) {
//and we add a new item to our list for
//each contact in our database
for (var i:Number = 0; i < result.data.length; i++) {
lister.addItem ({ label:result.data[i].nume + "-" +result.data[i].telefon
, nr:result.data[i].id });
}
}
}

Now to add some code to our buttons :

plus.addEventListener(MouseEvent.CLICK,adder);
xu.addEventListener(MouseEvent.CLICK,closeapp);
back.addEventListener(MouseEvent.MOUSE_DOWN,drag);
//because my buttons are not real buttons
//but movieclips i need to set the
//buttonMode property to true
plus.buttonMode=true;
xu.buttonMode=true;

function adder(e:MouseEvent):void{
//remove the eventlistener and move to the
//next frame
plus.removeEventListener(MouseEvent.CLICK,adder);
nextFrame();
}

function closeapp(e:MouseEvent):void {
//close the application
NativeApplication.nativeApplication.exit();
}

function drag(e:MouseEvent):void {
//drag the application
this.stage.nativeWindow.startMove();
}

You’ve finished the first frame, it’s time to go to the second frame where we add the contacts. Start by adding the next code:

//this line restricts the user input
//to just numbers in the phone input box
tel.restrict="0-9";
//add a new event listener to our plus button
plus.addEventListener(MouseEvent.CLICK,adder2);

Now create the final function that adds a new contact in the database:

function adder2(e:MouseEvent):void {
//create a new sql statement variable
var sql:SQLStatement=new SQLStatement();
sql.sqlConnection=conn;
//the next sql command creates a new entry
//in the table contacte from our database
sql.text =  "INSERT INTO contacte(nume, " +
"telefon)" +
"VALUES(@nume, " +
"@telefon)";
//to insert variables into sql commnads
//we use the parameters definition
sql.parameters["@nume"]=nume.text;
sql.parameters["@telefon"]=tel.text;
//add a new event listener that calls the
//function that retrieves the data
sql.addEventListener(SQLEvent.RESULT,retrieveData);
sql.execute();
//go to frame no. 1
prevFrame();
//remove the eventlistener from our plus button
plus.removeEventListener(MouseEvent.CLICK,adder2);
}

Now you can test the application like you would normaly do (CTRL+Enter on windows or command+enter on Mac). This is how my finished application looks like on desktop.

Now to publish the file as an Air application, so that other users can use the application, go to File>AIR Settings . A new window will appear; you can set whatever names in there but be sure to set the Window Style to Custom Chrome (transparent). Press the Publish AIR file button that creates an air installer file in the same directory where you’ve saved your .fla file. Here is the finished source file.

This tutorial is just to get you started on using Adobe AIR. It is not a complete application, because there are some missing functions. For example there is no checking to see that the users input is not empty. You can not delete or  modify a contact and the list could go on, the only limit is your imagination. If you want to add extra features to your application, you should use the same techniques shown in this tutorial. For more Sql commands you should use google or ask Maximilian to search what you want to modify in the database.

Articol favorit

Avand in vedere ca nu ne putem lauda la toata lumea cu noile noastre carti de vizita, ne-am gandit sa vi le prezentam intr-un mod inedit si in acelasi timp sa ne “jucam” un pic in Flash. Pe langa Flash am adaugat si putin Papervision3D 2.0 si pentru umbra o clasa aparte numita ShadowCaster. Vizionare placuta!

Articol favorit

Pornim prin a creea un nou document flash ActionScript 3.0. Salvam acest document cu numele de Spectrum.fla, apoi selectăm primul keyframe al acestui document si apasam tasta F9 pentru a ne aduce in fata fereastra de programare.

Pasul 1

In fereastra de programare introducem urmatoarea linie de cod:

var muzica=new Sound(new URLRequest(“song.mp3″));

Pasul 3

Aici declaram variabila muzica fiind de tipul Sound, iar pentru a incarca melodia noastra,song.mp3,(care se afla an acelasi director cu Spectrum.fla) folosim comanda new URLRequest.

Apoi adaugam o noua variabila ce va tine toată informatia de care avem nevoie pentru a creea Spectrumul.

var ba:ByteArray= new ByteArray();

Pasul 3

Dupa care adaugam o noua variabila de tip Sprite ce va contine toata grafica necesara si o adaugam pe scena principala.

var grafica:Sprite=new Sprite();

addChild(grafica);

Pasul 4

Urmeaza sa construim o noua functie numita loop care ne va procesa toata informatia

function loop(e:Event):void{

}

Pasul 5

In interiorul functiei loop adaugam urmatoarele linii de cod:

grafica.graphics.clear();
grafica.graphics.lineStyle(1,0×000000);
grafica.graphics.beginFill(0×000000);

Pasul 6

Aceasta linie de cod ne sterge orice am “desenat” in pasii anteriori

grafica.graphics.clear();

Aceasta linie de cod defineste stilul liniei, cifra 1 reprezentand grosimea liniei, iar 0×000000 reprezinta culoarea neagra in sistem hexadecimal

grafica.graphics.lineStyle(1,0×000000);

Aceasta linie de cod ne defineste culoarea care va “umple” Spectrumul, in cazul nostru folosim tot culoarea neagra

grafica.graphics.beginFill(0×000000);

Acum vom folosi functia din flash ,SoundMixer.computeSpectrum , ce ne va oferi informatii legate de melodie

SoundMixer.computeSpectrum(ba,true);

Pasul 7

Dupa care vom creea un ciclu for care ne va “desena” spectrumul prin functia drawRect

for(var i:uint=0; i<512;i++){

var num:Number=-ba.readFloat()*100-10;

sp.graphics.drawRect(i,200,1,num);

}

Pasul 8

Iar acum adaugam un event listener pentru scena

addEventListener(Event.ENTER_FRAME, loop);

Si apelam functia play

muzica.play();

Pasul 9

Apoi testam aplicatia cu tastele CTRL+Enter si obtinem urmatorul rezultat:

Rezultat

Acum puteti experimenta cu acest cod pentru a obtine mai multe rezultate. De exemplu daca schimam urmatoarea linie de cod

SoundMixer.computeSpectrum(ba,false);

Vom obtine

Rezultat 2

Daca schimbati in ciclul for

for(var i:uint=0; i<256;i++)

veti obtine un spectrum calculat doar pentru un canal audio.Putem seta pozitia pe orizontala a elementului grafica

grafica.x=20;

iar apoi facem urmatoarele modificari in ciclul for

for(var i:uint=0; i<256;i=i+4){

var num:Number=-ba.readFloat()*100-1;

grafica.graphics.drawRect(i,200,1,num);

}

Pentru a obtine urmatorul rezultat:

Apasa aici pentru a descarca sursele.

Articol favorit